Sparkler

Flash required: You need version 9 or later of the free Flash player from Adobe to use this content. To download and install the free player from Adobe’s web site click here.

Source code

This example uses the FollowMouse activity to cause the emitter to follow the mouse around. It is created in a single document class as follows

package
{
  import flash.display.Sprite;
  import flash.filters.BlurFilter;
  import flash.filters.ColorMatrixFilter;
  import flash.geom.Point;
  import flash.geom.Rectangle;
  
  import org.flintparticles.actions.*;
  import org.flintparticles.activities.FollowMouse;
  import org.flintparticles.counters.*;
  import org.flintparticles.displayObjects.Line;
  import org.flintparticles.emitters.Emitter;
  import org.flintparticles.initializers.*;
  import org.flintparticles.renderers.*;
  import org.flintparticles.zones.*;  

  public class Sparkler extends Sprite
  {
    private var emitter:Emitter;

    public function Sparkler()
    {
      emitter = new Emitter();

      emitter.counter = new Steady( 150 );
      
      emitter.addActivity( new FollowMouse() );
      
      emitter.addInitializer( new SharedImage( new Line( 8 ) ) );
      emitter.addInitializer( new ColorInit( 0xFFFFCC00, 0xFFFFCC00 ) );
      emitter.addInitializer( new Velocity( new DiscZone( new Point( 0, 0 ), 200, 350 ) ) );
      emitter.addInitializer( new Lifetime( 0.2, 0.4 ) );
      
      emitter.addAction( new Age() );
      emitter.addAction( new Move() );
      emitter.addAction( new RotateToDirection() );
      
      var renderer:BitmapRenderer = new BitmapRenderer( new Rectangle( 0, 0, 400, 400 ) );
      renderer.addFilter( new BlurFilter( 2, 2, 1 ) );
      renderer.addFilter( new ColorMatrixFilter( [ 1,0,0,0,0,0,1,0,0,0,0,0,1,0,0,0,0,0,0.95,0 ] ) );
      emitter.renderer = renderer;
      addChild( renderer );
      
      emitter.start( );
    }
  }
}